package 
{
 import flash.display.Sprite;
 import flash.events.Event;
 import flash.events.MouseEvent;
 import flash.events.ProgressEvent;
 import flash.events.TimerEvent;
 import flash.media.Video;
 import flash.net.FileFilter;
 import flash.net.FileReference;
 import flash.net.NetConnection;
 import flash.net.NetStream;
 import flash.net.URLRequest;
 import flash.text.TextField;
 import flash.text.TextFieldAutoSize;
 import flash.text.TextFormat;
 import flash.utils.ByteArray;
 import flash.utils.Timer;
 
 /**
  * ...
  * @author Patric Jonsson
  */
 public class Main extends Sprite 
 {
 private var uploadURL:URLRequest;
        private var file:FileReference;
 
 private var firsthalf:ByteArray;
 private var secondhalf:ByteArray;
 private var netstream:NetStream;
 private var video:Video;
 private var infotext:TextField;
 
 public function Main():void 
 {
 if (stage) init();
 else addEventListener(Event.ADDED_TO_STAGE, init);
 }
 
 private function init(e:Event = null):void 
 {
 removeEventListener(Event.ADDED_TO_STAGE, init);
 // entry point
 
 var format:TextFormat = new TextFormat("_sans");
 infotext = new TextField();
 infotext.selectable = false;
 infotext.text = "Click on stage to browse for a Flash video (*.flv) to play :-)";
 infotext.autoSize = TextFieldAutoSize.CENTER;
 infotext.setTextFormat(format);
 infotext.x = (stage.stageWidth - infotext.width) / 2;
 infotext.y = (stage.stageHeight - infotext.height) / 2;
 addChild(infotext);
 
 stage.addEventListener(MouseEvent.CLICK, onClick);
 }
 
 private function onClick(e:MouseEvent):void 
 {
 uploadURL = new URLRequest();
 file = new FileReference();
 
            file.addEventListener(Event.COMPLETE, completeHandler);
            file.addEventListener(Event.SELECT, selectHandler);
            file.addEventListener(ProgressEvent.PROGRESS, progressHandler);
 
 file.browse(new Array(new FileFilter("Flash video: (*.flv)", "*.flv")));
 }
        private function selectHandler(event:Event):void 
 {
            var file:FileReference = FileReference(event.target);
            file.load();
        }
        private function progressHandler(event:ProgressEvent):void 
 {
            var file:FileReference = FileReference(event.target);
 infotext.text = Math.ceil(event.bytesLoaded / event.bytesTotal) * 100+"% loaded";
        }
 
        private function completeHandler(event:Event):void 
 {
 removeChild(infotext);
 stage.removeEventListener(MouseEvent.CLICK, onClick);
 
            var file:FileReference = FileReference(event.target);
 var bytearray:ByteArray = file.data;
 bytearray.position = 0;
 
 firsthalf = new ByteArray();
 firsthalf.writeBytes(bytearray, 0, bytearray.length / 2);
 firsthalf.position = 0;
 
 bytearray.position = 0;
 secondhalf = new ByteArray();
 secondhalf.writeBytes(bytearray, bytearray.length / 2, bytearray.length / 2);
 secondhalf.position = 0;
 
 var t:Timer = new Timer(2000,1);
 t.addEventListener(TimerEvent.TIMER_COMPLETE, onTimerComplete);
 t.start();
 
 var netconnection:NetConnection = new NetConnection();
 netconnection.connect(null);
 
 netstream = new NetStream(netconnection);
 
 var callbackClient:Object = new Object();
 callbackClient.onMetaData = onMetaData;
  
 netstream.client = callbackClient;
 netstream.play(null);
 netstream.appendBytes(firsthalf);
 
 video = new Video();
 video.attachNetStream(netstream);
 
 addChild(video);
 }
 
 private function onTimerComplete(e:TimerEvent):void 
 {
 e.currentTarget.removeEventListener(TimerEvent.TIMER_COMPLETE, onTimerComplete);
 netstream.appendBytes(secondhalf);
 }
 
 public function onMetaData(info:Object):void
 {
 video.width = info.width;
 video.height = info.height;
 video.x = (stage.stageWidth - video.width) / 2;
 video.y = (stage.stageHeight - video.height) / 2;
 }
 }
}